【物聯網系統開發】運用 ARDUINO 乙太網路擴充板建立用戶端工具程式

Telnet 用戶端程式測試程式(TelnetClient)

/*

  Telnet client

 This sketch connects to a a telnet server (http://www.google.com)

 using an Arduino Wiznet Ethernet shield.  You'll need a telnet server

 to test this with.

 Processing's ChatServer example (part of the network library) works well,

 running on port 10002. It can be found as part of the examples

 in the Processing application, available at

 http://processing.org/

 Circuit:

 * Ethernet shield attached to pins 10, 11, 12, 13

 created 14 Sep 2010

 modified 9 Apr 2012

 by Tom Igoe

 */

#include <SPI.h>

#include <Ethernet.h>

// Enter a MAC address and IP address for your controller below.

// The IP address will be dependent on your local network:

byte mac[] = {

  0xAA, 0xBB, 0xCC, 0xDD, 0xEE, 0xFF

};

IPAddress ip(192, 168, 30, 200);

IPAddress dnServer(168, 95, 1, 1);

// the router's gateway address:

IPAddress gateway(192, 168, 30, 254);

// the subnet:

IPAddress subnet(255, 255, 255, 0);

// Enter the IP address of the server you're connecting to:

IPAddress server(140, 112, 172, 11);

// Initialize the Ethernet client library

// with the IP address and port of the server

// that you want to connect to (port 23 is default for telnet;

// if you're using Processing's ChatServer, use  port 10002):

EthernetClient client;

void setup() {

  // start the Ethernet connection:

  Ethernet.begin(mac, ip, dnServer, gateway, subnet);

  // Open serial communications and wait for port to open:

  Serial.begin(9600);

  while (!Serial) {

    ; // wait for serial port to connect. Needed for Leonardo only

  }

  // give the Ethernet shield a second to initialize:

  delay(1000);

  Serial.println("connecting...");

  // if you get a connection, report back via serial:

  if (client.connect(server, 23)) {

    Serial.println("connected");

  }

  else {

    // if you didn't get a connection to the server:

    Serial.println("connection failed");

  }

}

void loop()

{

  // if there are incoming bytes available

  // from the server, read them and print them:

  if (client.available()) {

    char c = client.read();

    Serial.print(c);

  }

  // as long as there are bytes in the serial queue,

  // read them and send them out the socket if it's open:

  while (Serial.available() > 0) {

    char inChar = Serial.read();

    if (client.connected()) {

      client.print(inChar);

    }

  }

  // if the server's disconnected, stop the client:

  if (!client.connected()) {

    Serial.println();

    Serial.println("disconnecting.");

    client.stop();

    // do nothing:

    while (true);

  }

}

文字型Browser用戶端程式(WebClient)

/*

  Web client

 This sketch connects to a website (http://www.google.com)

 using an Arduino Wiznet Ethernet shield.

 Circuit:

 * Ethernet shield attached to pins 10, 11, 12, 13

 created 18 Dec 2009

 by David A. Mellis

 modified 9 Apr 2012

 by Tom Igoe, based on work by Adrian McEwen

 */

#include <SPI.h>

#include <Ethernet.h>

// Enter a MAC address for your controller below.

// Newer Ethernet shields have a MAC address printed on a sticker on the shield

byte mac[] = {

  0xAA, 0xBB, 0xCC, 0xDD, 0xEE, 0xFF

};

IPAddress ip(192, 168, 30, 200);

IPAddress dnServer(168, 95, 1, 1);

// the router's gateway address:

IPAddress gateway(192, 168, 30, 254);

// the subnet:

IPAddress subnet(255, 255, 255, 0);

// if you don't want to use DNS (and reduce your sketch size)

// use the numeric IP instead of the name for the server:

//IPAddress server(74,125,232,128);  // numeric IP for Google (no DNS)

char server[] = "www.google.com";    // name address for Google (using DNS)

// Initialize the Ethernet client library

// with the IP address and port of the server

// that you want to connect to (port 80 is default for HTTP):

EthernetClient client;

void setup() {

  // Open serial communications and wait for port to open:

  Serial.begin(9600);

  while (!Serial) {

    ; // wait for serial port to connect. Needed for Leonardo only

  }

  // start the Ethernet connection:

  if (Ethernet.begin(mac) == 0) {

    Serial.println("Failed to configure Ethernet using DHCP");

    // no point in carrying on, so do nothing forevermore:

    // try to congifure using IP address instead of DHCP:

      Ethernet.begin(mac, ip, dnServer, gateway, subnet);

  }

  // give the Ethernet shield a second to initialize:

  delay(1000);

  Serial.println("connecting...");

  // if you get a connection, report back via serial:

  if (client.connect(server, 80)) {

    Serial.println("connected");

    // Make a HTTP request:

    client.println("GET /search?q=arduino HTTP/1.1");

    client.println("Host: www.google.com");

    client.println("Connection: close");

    client.println();

  }

  else {

    // kf you didn't get a connection to the server:

    Serial.println("connection failed");

  }

}

void loop()

{

  // if there are incoming bytes available

  // from the server, read them and print them:

  if (client.available()) {

    char c = client.read();

    Serial.print(c);

  }

  // if the server's disconnected, stop the client:

  if (!client.connected()) {

    Serial.println();

    Serial.println("disconnecting.");

    client.stop();

    // do nothing forevermore:

    while (true);

  }

}

吳佳駿 (Chia-Chun Wu)，國立中興大學資訊科學與工程學系博士，現任教於國立金門大學工業工程與管理學系專任助理教授，目前兼任國立金門大學計算機與網路中心資訊網路組組長，主要研究為軟體工程與應用、行動裝置程式設計、物件導向程式設計、網路程式設計、動態網頁資料庫、資訊安全與管理。

Email: ccwu0918@nqu.edu.tw

許智誠 (Chih-Cheng Hsu)，美國加州大學洛杉磯分校(UCLA) 資訊工程系博士，曾任職於美國 IBM 等軟體公司多年，現任教於中央大學資訊管理學系專任副教授，主要研究為軟體工程、設計流程與自動化、數位教學、雲端裝置、多層式網頁系統、系統整合。

Email: khsu@mgt.ncu.edu.tw

蔡英德 (Yin-Te Tsai)，國立清華大學資訊科學系博士，目前是靜宜大學資訊傳播工程學系教授、靜宜大學計算機及通訊中心主任，主要研究為演算法設計與分析、生物資訊、軟體開發、視障輔具設計與開發。

Email:yttsai@pu.edu.tw